Macro Plugin PortuguêsBR

Instalação no OpenKore

1. Download o plugin de macro.
2. Acesse sua pasta do OpenKore (a pasta que contém o arquivo openkore.pl).
3. Nesta pasta crie uma subpasta chamada plugins, se já não houver uma.
4. Dentro do arquivo zip do plugin de macro você econtrará o arquivo macro.pl e a pasta Macro. Extraia-os para a pasta plugins.
5. Na pasta control do seu OpenKore crie um arquivo em branco chamado macros.txt. Nele você adicionará suas macros/automacros.

Depois da instalação, a árvore de arquivos do seu OpenKore será similar a (ignorando os arquivos próprios do OpenKore):

openkore
|-- openkore.pl
|-- control
|   `-- macros.txt
|-- fields
|-- logs
|-- plugins
|   |-- Macro
|   |   |-- Automacro.pm
|   |   |-- Data.pm
|   |   |-- Parser.pm
|   |   |-- Script.pm
|   |   `-- Utilities.pm
|   |-- macro.pl
|-- src
`-- tables

Instalação no VisualKore

1. Download plugin de macro.
2. Dentro do arquivo zipado do plugin de macro você encontrará o arquivo macro.pl e a pasta Macro. Extraia-os para C:\Program Files\VisualKore\plugins
3. Acesse a janela Profiles do VisualKore . Selecione seu perfil e clique em "Edit Profile".
4. Uma pasta irá aparecer, nela crie um arquivo vazio chamado macros.txt. Neste arquivo você colocará suas macros/automacros.

Para configurar o plugin procure em Configuração de arquivos.

Notas:

• Cada pasta de perfil do seu VisualKore corresponde a pasta "control" referenciado neste manual.
• Para utilizar a mesma macro em múltiplos perfis, você deverá copiar o arquivo macros.txt(sua macro) para cada perfil. Além disso, cada config.txt do seu perfil deve possuir a linha de código que previne o plugin de ser descarregado/desligado.
• Por favor leia todo o manual para buscar a linha de código que você precisa adicionar em seu config.txt na pasta de seu perfil. Se o código não for inserido o plugin será descarregado/desligado.

macro <nome da macro> [opções] [-- parâmetro(s)]

Executa a macro <nome da macro>.

Parâmetros para a macro podem ser especificados após o uso de dois hífens(--). Estes parâmetros são salvos nas variáveis $.param1 to $.paramN. Exemplo:

macro foo {
 log Parâmetro 1 é $.param1
 log Parâmetro 2 é $.param2
}

quando executada como macro foo -- foo bar apresentará

[macro] Parâmetro 1 é foo
[macro] Parâmetro 2 é bar

macro list

Lista todas as macros disponíveis.

macro stop

Pára a macro atual.

macro pause

Interrompe a execução da macro.

macro resume

Reinicia uma macro interrompida.

macro set variáve valor

Configura/troca variável para valor ou apaga variável se nenhum valor é dado.

macro version

Imprime o número da versão.

macro reset [<nome(s)>]

Reseta todas as automacros que executam uma única vez ou a automacro especificada em <nome>.

macro status

Mostra quando uma macro está ou não em execução. Se estiver em execução mostra o atraso para o próximo comando, a linha atual, configruação de overrideAi, quando ou se a macro foi encerrada e se a macro está ou não registrada na fila de AI.

control/macros.txt

Coloque suas macros e automacros aqui.

control/timeouts.txt

Adicione o macro_delay e configure para o número de segundos que você deseja que o plugin pause entre os commandos.

control/config.txt

Certifique-se de ler esse manual por completo.
Se você quiser usar comandos do OpenKore em suas macros leia sobre Commands comandos de console. Note que alguns comandos como de manipulação da fila de IA não são permitidos.
Finalmente, leia os anúncios. Eles podem conter exemplos úteis.

macro foo {
   faça isso..
   e aquilo..
   blábláblá..
}

Na teoria você pode usar qualquer comando de console em uma macro. Eu testei este plugin para comprar flechas de prata, conversar com NPC e mandar mensagens privadas para pessoas. Pessoas preguiçosas podem usar este plugin para completar a quest de amtsu ou algo similar.

do <comando>

Permite que o OpenKore execute o <comando>.

Example:

 macro foo {
    do move 123 234 prontera
    do sit
    do c "Olá mundo"
 }

log <texto>

Envia o <texto> para o console.

Example:

macro foo {
   log Esta linha registra um texto no console.
   log Toda sua base pertence a nós!
}

pause [<n>]

Pausa por um ou <n> segundos.

Example:

 macro foo {
    log Eu estou aqui e...
    pause 10
    log agora estou aqui.
 }

call <nome da macro> [<n>]

Executa a macro <nome da macro> [<n> vezes]. Quando <nome da macro> termina a macro atual continua a execução.

release (<nome> | all)

Reabilita a execução de uma automacro travada (parâmetro "run-once" ou travada por "lock") ou reabilita todas as automacros quando utilizando release all.

lock <nome>

Trava uma automacro e deasbilita sua verificação.

stop

Encerra imediatamente a macro em execução.

set <opção> <valor>

Configura caracterísitcas da macro:

• orphan método
• macro_delay timeout
• overrideAI [0|1]
• repeat vezes
• exclusive [0|1]

Veja a seção de automacro.

Declaração e uso de variáveis

Você pode definir e trabalhar com suas próprias variáveis.
Para configurar uma variável use $variable = valor, para reutilziar o valor use $variable.
É possível incrementar e decrementar a variável usando $variable++ ou $variable--.
Para cálculos utilize @eval. Para extrair o primeiro item de uma lista separada por vígula utilize

macro foo {
  $list = elemento um,elemento dois,foo,bar,baz
  $var = [$list]
  log var contains $var (elemento um)
  log list contains $list (elemento dois,foo,bar,baz)
}

Note que os nomes de variáveis devem começar com uma letra e só podem conter letras e dígitos.

Example:

macro foo {
   $var1 = mundo
   $var2 = olá
   $var3 = $var2 $var1
   log a próxima linha apresentarán "olá mundo . mundo . olá"
   do c $var3 . $var1 . $var2
   $var4 = 47
   log \$var4 é $var4
   $var4++
   log \$var4 é $var4
   $var4 = @eval ($var4 + 52)
   log \$var4 é $var4
}

Variáveis Especiais

Essas são variáveis especiais apenas para leitura que começam com um ponto.

• $.map - o mapa em que você se encontra ("prontera")
• $.pos - sua posição atual ("123 234")
• $.time - horário atual formatado como no Unix ("1131116304")
• $.datetime - data e hora atuais ("Fri Nov 4 15:59:36 2005")
• $.hp - hp atual
• $.sp - sp atual
• $.lvl - nível de base atual
• $.joblvl - nível de job atual
• $.spirits - quantidade atual de esferas espirituais
• $.zeny - quantidade atual de zeny
• $.status - status atual em uma lista separada por vírgula
• $.lastLogMsg - o texto que acionou a condição da última automacro
• $.lastpub - o nome do jogador que acionou a condição "pubm" da última automacro
• $.lastpubMsg - o que ele escreveu
• $.lastpm - o nome do jogador que acionou a condição "pm" da última automacro
• $.lastpmMsg - o que ele escreveu
• $.lastguild - o nome do jogador que acionou a condição "guild" da última automacro
• $.lastguildMsg - o que ele escreveu
• $.lastparty - o nome do jogador que acionou a condição "party" da última automacro
• $.lastpartyMsg - o que ele escreveu
• $.lastMonster - o nome do monstro que acionou a condição "monster" da última automacro
• $.lastMonsterPos - a última posição conhecida do monstro ("123 234 prontera")
• $.lastMatchN - última referência de comparação positiva de regexp.
• $.paramN - parâmetros de linha de comando (veja comandos)
• $.caller - nome da última automacro acionada
• $.hooksave - valor de uma hash key (argumento repassado pelo o hook)
• $.weight Peso atual do personagem
• $.maxweight Peso máximo do personagem

Variáveis encadeadas(Nested variables)

Você pode definir variáveis dinâmicas ou variáveis encadadeadas.

Example:

macro foo {
    $var = foo
    log \$var is "foo"
    ${$var} = bar
    log \$\$var is \$foo is "bar"
}

Controle de fluxo e labels

Enquanto todas as linguagens de programação de alto nível possuem construções como "if .. then", "while", "repeat", "for .. next", "do .. while", as funções executam seus denominadores mais comuns que são "if", "goto" and "while". E é por isso que o plugin de macro só suporta essas três palavras chaves. Apesar de não existir número de linhas(visíveis) você vai precisar usar labels que são definidas por dois pontos seguidos do nome da label.

Exemplo de uma construção "while":

macro foo {
    $i = 0
    log as próximas linhas irão entrar em loop por 11 vezes (0 .. 10)
    while ($i <= 10) as exampleloop
    	log loop $i
    	$i++
    end exampleloop
}

Example:

macro foo {
   $i = @random ("1", "2", "3")
   if ($i == 1) goto um
   if ($i == 2) goto dois
   log i is three.
   goto end
   :um
   log i é um
   goto end
   :two
   log i é dois
   :end
}

Nota: labels goto só podem conter letras e dígitos. Exemplo: warp_to_payon não funciona, deve ser algo parecido com warpToPayon.

Condições

Palavras-chaves especiais

@npc (<x> <y>)

Expõe o ID de NPC que está localizado em (<x>,<y>), ou para -1 se o NPC não for localizado.

@inventory (<item>)

Procura em seu inventário pelo <item> e retorna o ID ou -1 se o item não foi encontrado.

@Inventory (<item>)

Mesmo que @inventory mas retorna todas as IDs que combinarem em uma lista separada por vírgula ou -1 se o item não for localizado.

@cart (<item>)

Procura em seu carrinho pelo <item> e retorno o ID ou -1 se não for encontrado.

@Cart (<item>)

Igual a @cart mas retorna todos os IDs que combinarem em uma lista separada por vírgula ou -1 se o item não for encontrado.

@storage (<item>)

Pesquisa pelo <item> em seu inventário e retorna a ID ou -1 se não for localizado.

@Storage (<item>)

O mesmo que @storage mas retorna todos os IDs que combinarem em uma lista separada por vírgula e -1 se o item não for localizado.

@player (<nome>)

Procurar por um jogador e retorna o ID ou -1 se não for localizado.

@vender (<nome>)

Procura por um vendedor e retorna o ID ou -1 se não for localizado.

@store (<nome>)

Procura por um item na loja e retorna seu ID ou -1 se não for encontrado.

@random ("<argumento1>"[, "<argumento2>"[, ...]])

Retorna um dos argumentos dados aleatóriamente.

@rand (<n>, <m>)

Retorna um número aleatório entre(e incluindo) <n> e <m>.

@invamount (<item>)

Retorna a quantidade do <item> no invertário.

@cartamount (<item>)

Retorna a quantidade do <item> no carrinho.

@shopamount (<item>)

Retorna a quantidade do <item> na vendinha.

@storamount (<item>)

Retorna a quantidade do <item> no inventário.

@eval (<argumento>)

Analisa o <argumento> dado.

@arg ("<argumento>", <n>)

Retorna a letra na posição <n> do argumento dado ou uma string vazia se o índice estiver fora de alcance.

@config (<variável>)

Retorna o valor da <variável> especificada no config.txt

@venderitem (<nome>)

Olha por um item no mercado de jogadores e retorna ID se encontrado, ou -1 se o item não foi encontrado.

@venderprice (<indexID>)

Olha por um item no mercado de jogadores e retorna o preço.

Comandos "encadeados"

Você pode executar múltiplos comandos um após o outro sem ter que esperar pela IA do OpenKore ou macro_delay ou outra coisa. Apenas encadeie os comandos com "[" e "]".

Exemplo (com linhas numeradas):

0 macro foo {
1  do algo
2  log ainda outra linha
3  [
4     do alguma coisa
5     do outra coisa
6     log foo
7  ]
8  log pronto
9 }

A linha 3 inicia o modo encadeado. Essa linha não tem atraso. As linhas 4,5 e 6 são executadas assim que o comando anterior terminar, sem atraso e eles não podem ser interrompidos. A linhas 7 interrompe o modo encadeado e a linha 8 executará $macro_delay segundos após.

Exemplo simples de macro

Example:

macro foo {
   $foobegin = $.pos
   do move 168 128 prt_in
   do talk @npc (172 130)
   do store
   do store
   do buy @store (Silver Arrow) 10000
   do move 280 198 prontera
   do talk @npc (282 200)
   do talk cont
   do talk resp 1
   do storage add @inventory (Silver Arrow) @eval (@invamount (Silver Arrow) - 1000)
   do move $foobegin
}

Quando acionada pelo comando "macro foo [times]" a macro faz o seguinte:

• armazena a posição atual em "foobegin";
• move-se para 168 128 prt_in (weapon shop);
• conversa com o NPC localizado em 172 130 (vendedor de armas);
• digita "store" duas vezes para mostrar o que ele vende;
• compra 10,000 flechas de prata;
• move-se para 280 198 prontera (portal leste de Prontera);
• conversa com a kafra;
• responde cont(continuar) e resp(opção) 1 e abre o armazém;
• adiciona todas as flechas de prata com exceção de 1000 ao armazém;
• e finalmente retorna para onde estávamos antes de executar a macro.

Sintaxe de automacro

Comentários

Macros Órfãs

Por fazer/Bugs conhecidos/Limitações conhecidas

Download

Versão em desenvolvimento (SVN)

Extras

Dúvidas freqüentes(FAQ)

Discussão no fórum

Para discussão e suporte acesse o fórum de plugin de macro.

Licença

O plugin de macro é licenciado sob GNU General Public License v2.

Autor

Escrito por arachno <arachnophobia at users dot sourceforge dot net>